Função COUNTIF (Contar.se) no Excel

Função COUNTIF (Contar.se) no Excel

Resumo

CONTAR.SE (Countif) é uma função do Excel que conta células que correspondem a uma condição única num determinado intervalo de dados. Pode ser usado para contar células com datas, números ou texto. E suporta os operadores lógicos >, <, <>, = e os wildcards *, ? para pesquisa parcial.

Sintaxe

=CONTAR.SE (intervalo; critério)

Argumentos

intervalo // o intervalo de células que queremos contar
critério // o critério que define que células contamos

1. Utilização do CONTAR.SE (Countif) para contar células maiores ou iguais que determinado valor [Célula J5]

=CONTAR.SE($G$4:$G$19;">=100")
=CONTAR.SE($G$4:$G$19; // o intervalo de células que queremos contar
">=100") // o critério que queremos procurar, neste caso, vendas maiores ou iguais a 100

Regra geral, células com texto necessitam de ser colocadas entre aspas ("") e números não. Contudo, se queremos usar um operador em conjunto com o número (neste caso: ">=100") temos que colocar as aspas.

2. Utilização do CONTAR.SE (Countif) para contar células que correspondam a um determinado texto [Célula J6]

=CONTAR.SE($F$4:$F$19;"F")
=CONTAR.SE($F$4:$F$19; // o intervalo de células que queremos contar
"F") // o critério que queremos procurar, neste caso, vendedores de Sexo Feminino representado por "F"

3. Utilização do CONTAR.SE (Countif) para contar células que correspondam a um determinado valor noutra célula [Célula J7]

=CONTAR.SE($D$4:$D$19;I7)
=CONTAR.SE($D$4:$D$19; // o intervalo de células que queremos contar
I7) // o critério que queremos procurar e que se encontra numa célula adjacente (I7)

4. Utilização do CONTAR.SE (Countif) para contar células que contenham uma parte de um texto usando um wildcard [Célula J8]

=CONTAR.SE($C$4:$C$19;"*jo*")
=CONTAR.SE($C$4:$C$19; // o intervalo de células que queremos contar
"*jo*") // todas as células que contenham este texto (jo) serão contabilizadas

A Função CONTAR.SE (Countif) não é Case-Sensitive, ou seja, podemos escrever "JO", "Jo", "jO", "jo", e a contagem devolvida será sempre a mesma.

5. Outras utilizações do CONTAR.SE (Countif): Células Vazias, Não Igual, Datas

5.1 Função CONTAR.SE (Countif) para contar Células Vazias

=CONTAR.SE($C$4:$C$19;"<>") // conta células não vazias
=CONTAR.SE($C$4:$C$19;"") // conta células vazias

5.2 Função CONTAR.SE (Countif) para contar células diferentes de determinado valor

=CONTAR.SE($D$4:$D$19;"<>Portugal") // conta células com valor diferente de "Portugal"

5.3 Função CONTAR.SE (Countif) com Datas

A forma mais prática de usar a Função CONTAR.SE (Countif) com datas é usar uma data numa célula adjacente. Sendo necessário concatenar a célula adjacente, usando "&" para ligar o operador ao valor de data dessa célula.

Data 1
=CONTAR.SE($L$4:$L$10;">"&I15)
=CONTAR.SE($L$4:$L$10; // o intervalo de células que queremos contar
">"&I15) // o critério que queremos procurar e que se encontra numa célula adjacente (I15) concatenado (&) com o operador ">"

Data 2
=CONTAR.SE($L$4:$L$10;">"&DATA(2020;6;1))
=CONTAR.SE($L$4:$L$10; // o intervalo de células que queremos contar
">"&DATA(2020;6;1)) // o critério que queremos procurar com o operador ">" concatenado (&) com a utilização da Função DATA (Date)

Para utilizações mais complexas com elementos da data, por exemplo todas as datas em determinado mês ou datas entre duas datas diferentes, recomenda-se a Função CONTAR.SE.S (Countifs) que permite utilizar mais do que um critério de procura.

Descargas

Descarrega aqui o ficheiro com os exemplos para usar a função COUNTIF (Contar.se)
Artigo anterior Artigo seguinte
Sem comentários
Comentar
url comentário

Pesquisa Google