Encontrar Keywords e agrupar com a função TEXTJOIN

Resumo

Criar grupos (clusters) de dados com base numa lista de palavras-chaves encontradas nesses dados usando a Função TEXTJOIN (Unirtexto).

Encontrar as Keywords

=TEXTJOIN("; ";TRUE;IF(COUNTIF($A5; "*"&Keywords&"*");Keywords;""))

=TEXTJOIN("; "; // Começamos por definir o delimitador em que indicamos que este campo irá funcionar como separador entre as keywords encontradas. Neste exemplo, o delimitador deverá ser igual a "; "

TRUE; // No argumento seguinte, ignora_vazios, confirmamos que queremos que a fórmula ignore células vazias.

IF(COUNTIF($A5; "*"&Keywords&"*");Keywords;"")) // Por fim, fechamos a fórmula encadeando um IF (Se) com um COUNTIF (Contar.se) recorrendo à utilização de Wildcards em que cruzamos uma lista de keywords com a lista de frases a pesquisar. Sempre que a keyword é encontrada na frase ela será listada.

Com a utilização desta fórmula conseguimos assim encontrar e listar todas as keywords de pesquisa e chegamos a um primeiro nível de clusterização.

Frases Aleatórias	Keywords encontradas
Mcdonald's was the local hangout joint where the group usually ended up eating apples.	McDonald's; Apple
Apples and oranges caused the elderly lady to think about her past.	Apple; Orange
He swore he just saw his sushi move.	Sushi
Just because the water is red doesn't mean you can't drink it.	Water
A banana is not an hamburger.	Banana; Hamburger
The pigs were insulted that they were named hamburgers.	Hamburger
I don't respect anybody who can't tell the difference between Pepsi and Coke.	Pepsi; Coke
Everything was going so well until I was accosted by a purple giraffe.
It's not possible to convince a monkey to give you a banana by promising it infinite bananas when they die.	Banana

Agrupar de acordo com as Keywords

A partir do racional anterior podemos construir a fórmula com mais alguns elementos por forma a aproveitar as keywords encontradas agrupando-as em clusters mais finos.

=TEXTJOIN("; ";TRUE;UNIQUE(IF(COUNTIF($A5; "*"&Keywords&"*");Descrições;"")))

UNIQUE(IF(COUNTIF($A5; "*"&Keywords&"*");Descrições;""))) // Introduzimos a função UNIQUE (Exclusivos) para que ignore duplicações e alteramos o resultado lógico do IF (Se) para que devolva a nomenclatura dos clusters - neste exemplo "Descrições" - sempre que encontrar a keyword pesquisada.

Keywords	Descrições
McDonald's	Restaurante
Banana	Fruta
Apple	Fruta
Orange	Fruta
Sushi	Comida
Hamburger	Comida
Pepsi	Bebida
Coke	Bebida
Water	Bebida

Descargas

Descarrega aqui o ficheiro com os exemplos para encontrar keywords e agrupar com TEXTJOIN