Criar listas sequenciais de DATA e HORA com a função SEQUENCE

Criar listas sequenciais de DATAS com a função SEQUENCE

Resumo

Neste artigo mostramos-te como criar séries sequenciais de datas e horas recorrendo à Função SEQUENCE disponível no Excel 2021 e Excel 365. Se usares versões anteriores do Excel podes recorrer ao recurso de AUTO FILL para criar séries.

Séries de datas sequenciais com SEQUENCE

A função cria listas de números sequenciais numa array. Uma vez que para o Excel datas e horas são números, podemos usar ambos para gerar listas numéricas em que aplicamos formatos de data e hora nos resultados da função.

Criar uma série de datas sequenciais com SEQUENCE
Definir a primeira data da série
=SEQUENCE (linhas; [colunas]; [início]; [passo])
linhas // número de linhas a devolver
[colunas] // número de colunas a devolver [opcional]
[início] // valor de início, pré-definição é 1 [opcional]
[passo] // incremento que determina o intervalo entre os valores da sequência, pré-definição é 1 [opcional]

No argumento [início] vamos indicar o primeiro elemento da série. E podemos fazê-lo de 3 formas:
=SEQUENCE(8;1;"31/1/2021";1) // Escrever directamente na fórmula a data de ínicio que pretendemos
=SEQUENCE(8;1;DATE(2021;1;31);1) // Usar a função DATE para introduzir a data
=SEQUENCE(8;1;H4;1) // Usar uma célula como referência

Criar sequências de dias úteis com WORKDAY e SEQUENCE

Cria uma série de dias úteis
Série de dias úteis
=WORKDAY (data_início -1; SEQUENCE (número_de_dias) )
Para criar uma sequência que lista apenas dias úteis usamos a função SEQUENCE dentro da função WORKDAY. No primeiro argumento de WORKDAY vamos indicar a data de início da sequência e subtraímos -1 para que essa data seja incluída na sequência. No segundo argumento, usamos a função SEQUENCE para definir o número de registos que queremos na sequência.
=WORKDAY(B7-1;SEQUENCE(B6))
Neste caso, B7 é a célula que contém a data de início e B6 é o tamanho da sequência que queremos gerar. Usámos propositadamente uma data de início correspondente a um sábado para vermos a função workday a funcionar, excluíndo sempre sábados e domingos. Para incluir feriados deves usar a Função WORKDAY.INTL que nos permite customizar que dias queremos considerar como não úteis.

Criar sequências de meses com DATE e SEQUENCE

Cria uma série de meses
Série de meses
=DATE (ano_início ; SEQUENCE (número_de_meses) ; 1)
Para criar uma sequência que lista apenas meses usamos a função SEQUENCE dentro da função DATE. No primeiro argumento de DATE definimos o ano que queremos listar. No segundo argumento encaixamos a Função SEQUENCE onde definimos o tamanho da sequência, que será um valor entre 1 e 12. E no terceiro argumento definimos o dia da data.
=DATE(B7;SEQUENCE(B6);1)
B7 corresponde ao ano de 2022 e definimos que a sequência terá 12 linhas (correspondentes a cada um dos meses desse ano). E por fim indicamos que o valor da data é o dia 1. O resultado da fórmula é uma listagem de 12 campos com o primeiro dia de cada um dos meses do ano 2022.

Os valores da listagem são datas mas decidimos que os queremos mostrar como meses usando as opções de Formatos Personalizados das células em que a sequência está colocada.

m - 1
mm - 01
mmm - Jan
mmmm - Janeiro

Criar sequências de horas, minutos e segundos

Criar sequência de horas
Séries de horas
=SEQUENCE(3;1;B6;1/24)
Tal como as datas, as horas também são guardadas como números no Excel, com a particularidade de serem números decimais que representam frações do dia. Sendo números, a função SEQUENCE permite que a usemos para criar sequências.

No primeiro argumento definimos que queremos uma sequência de 3 linhas e no segundo argumento 1 coluna. No terceiro argumento apontamos à célula com a hora que queremos usar para iniciar a sequência (nos nossos exemplos 12:00:00) e no quarto argumento definimos o intervalo de incremento com o cálculo que pretendemos. Cada dia tem 24 hora, o que significa que podemos usar frações para criar estes intervalos de incremento:

1/12 para incrementar 2 horas
1/24 para incrementar 1 hora
1/48 para incrementar meia hora
1/96 para incrementar um quarto de hora

Outra forma de definir o intervalo da sequência é introduzir a função TIME no quarto argumento da função SEQUENCE substituíndo o cálculo com frações por três variáveis separadas que definem o incremento de horas (D7), minutos (D8) e segundos (D9).

Criar sequência de horas com função TIME
Função TIME para definir o intervalo de incremento
=SEQUENCE(B7;B8;B9;TIME(D7;D8;D9))

Descargas

Descarrega aqui o ficheiro com os exemplos do artigo para criar listas sequencias com a função SEQUENCE
Artigo anterior Artigo seguinte
Sem comentários
Comentar
url comentário

Pesquisa Google